assume cs:code

data segment
  db 32 dup (0)
  db 9, 8, 7, 4, 2, 0 
  db '/', '/', ' ', ':', ':'
data ends

code segment
start:
  mov ax, data
  mov ds, ax
  mov si, 0
  mov di, 32
  mov cx, 6
start1:
  push cx

  mov al, [di]
  out 70h, al
  in al, 71h
  
  mov ah, al
  mov cl, 4
  shr ah, cl
  and al, 0fh
  add ah, 30h
  add al, 30h
  mov [si], ah    ;第一位数字复制到内存中
  mov [si+1], al  ;第二位数字复制到内存中
  mov ah, [di+6]  
  mov [si+2], ah  ;第三位字符复制到内存中
  inc di
  add si, 3
  pop cx
  loop start1

  mov dh, 8
  mov dl, 3
  mov cl, 2
  mov si, 0
  call show_str
  mov ax, 4c00h
  int 21h

;名称：show_str 显示字符串子程序  
;功能：在指定的位置，用指定的颜色，显示一个用0结束的字符串  
;参数：(dh)=行号（取值范围0-24），(dl)=列号（取值范围0-79）  
;     (cl)=颜色，ds:si指向字符串的首地址  
;返回：无  
show_str:  
  push ax  
  push bx  
  push cx  
  push dx  
  push si  
  push es  

  mov ax, 0b800h  
  mov es, ax  
  mov al, 0a0h  
  mul dh  
  mov bx, ax  
  mov al, 2h  
  mul dl  
  add bx, ax  
  mov dl, cl  
  mov cx, 0  
s:  
  mov cl, [si]  
  jcxz ok  
  mov es:[bx], cl  
  mov es:[bx+1], dl  
  add bx, 2  
  inc si  
  jmp short s  
ok:  
  pop es  
  pop si  
  pop dx  
  pop cx  
  pop bx  
  pop ax  
  ret  
code ends
end start

=====================
assume cs:code

data segment
  db 32 dup ('$')
  db 9, 8, 7, 4, 2, 0 
  db '/', '/', ' ', ':', ':'
data ends

code segment
start:
  mov ax, data
  mov ds, ax
  mov si, 0
  mov di, 32
  mov cx, 6
start1:
  push cx

  mov al, [di]
  out 70h, al
  in al, 71h
  
  mov ah, al
  mov cl, 4
  shr ah, cl
  and al, 0fh
  add ah, 30h
  add al, 30h
  mov [si], ah
  mov [si+1], al
  mov ah, [di+6]
  mov [si+2], ah
  inc di
  add si, 3
  pop cx
  loop start1

  ;调整光标位置
  mov ah, 2 ;置光标
  mov bh, 0 ;第0页
  mov dh, 5 ;dh中放行号
  mov dl, 30 ;dl中放列号
  int 10h
  ;显示字符串
  mov dx, 0
  mov ah, 9
  int 21h

  mov ax, 4c00h
  int 21h

code ends
end start
============确实挺方便的:)===============