实验 15 安装新的 int 9 中断例程

安装一个新的 int 9 中断例程。
功能：在 DOS 下，按下“A”键后，除非不再松开，如果松开，就显示满屏幕的“A”，其他的键照常处理。
提示，按下一个键时产生的扫描码称为通码，松开一个键产生的扫描码称为断码。断码=通码+80h。

具体代码如下：

assume cs:code

stack segment
  db 128 dup (0)
stack ends

code segment

start:  mov ax,stack
     mov ss,ax
     mov sp,128

     push cs
     pop ds
                
     mov ax,0
     mov es,ax

     mov si,offset int9  ; 设置 ds:si 指向源地址
     mov di,204h    ; 设置 es:di 指向目的地址
     mov cx,offset int9end-offset int9  ; 设置 cx 为传输长度
     cld  ; 设置传输方向为正
     rep movsb

; 将外中断的原 int 9 例程入口地址转存到 0:200 和 0:202 单元
     push es:[9*4]
     pop es:[200h]
     push es:[9*4+2]
     pop es:[202h]

; 将外中断的新编写 int 9 例程入口地址存入中断向量表第 9 号表项所在处（参 12.3 节）
     cli
     mov word ptr es:[9*4],204h
     mov word ptr es:[9*4+2],0
     sti

     mov ax,4c00h
     int 21h

int9:  push ax
    push bx
    push cx
    push es

    in al,60h

    pushf
    call dword ptr cs:[200h]  ; 当此中断例程执行时 (CS)=0

    cmp al,9Eh  ; “A”字符的通码为 1Eh，断码=1Eh+80h=9Eh
    jne int9ret

    mov ax,0B800h
    mov es,ax
    mov bx,0
    mov cx,2000
s:   mov byte ptr es:[bx],'A'
    add bx,2
    loop s

int9ret:  pop es
      pop cx
      pop bx
      pop ax
      iret

int9end:  nop

code ends

end start