assume    cs:code
        code  segment
      start:
              mov       ax,cs
              mov       ds,ax
              mov       si,offset begin
              mov       ax,0
              mov       es,ax
              mov       di,204h
              mov       cx,offset over - offset begin
              cld
              rep       movsb
;修改向量表
              mov       ax,es:[9*4]
              mov       es:[200h],ax
              mov       ax,es:[9*4+2]
              mov       es:[202h],ax            ;保存了int9的向量表
              
              cli
              mov       ax,204h
              mov       es:[9*4],ax
              mov       ax,0
              mov       es:[9*4+2],ax
              sti
;退出
              mov       ax,4c00h
              int       21h
;中断处理程序        
      begin:
              push      ax
              push      ds
              push      si
              push      cx          ;保护现场
              
              in        al,60h
              
              pushf
              call      dword ptr cs:[200h]

              cmp       al,9eh
              jne       return
              
              mov       ax,0b800h
              mov       ds,ax
              mov       si,0        ;ds:si指向显存
              mov       al,'A'
              mov       cx,2000     ;循环次数
          s:
              mov       [si],al
              mov       ah,2
              mov       [si+1],ah
              add       si,2
              loop      s
     return:
              pop       cx          ;恢复现场
              pop       si
              pop       ds
              pop       ax
              iret
       over:  nop
        code  ends
              end       start