assume cs:code
code segment
  start:
      mov ax,code
      mov ds,ax
      mov si,offset int7ch
      
      mov ax,0
      mov es,ax
      mov di,200h
      
      mov cx,offset int7chend-offset int7ch
      cld
      rep movsb
      
      cli
      mov word ptr es:[4*7ch],200h
      mov word ptr es:[4*7ch+2],0
      sti
      
      
      mov ax,4c00h
      int 21h
      
   
;子程序说明如下
 ;(1)清屏  
 ;(2) 设置前景色
 ;（3) 设置背景色
 ;(4)向上滚动一行
 
 ;入口参数说明
 ;（1) 用ah寄存器传递功能号:0表示清屏 1表示设置前景色 2表示设置背景色3表示向上滚动一行
 ;(2) 对于2 3 号功能，用al 传送颜色值，al 0~7




;------------------int 7ch
int7ch:
    jmp short set
    table dw sub0-int7ch+200h,sub1-int7ch+200h,sub2-int7ch+200h,sub3-int7ch+200h
    set:
      push bx
      
      cmp ah,3
      ja ok
      mov bl,ah
      mov bh,0
      add bx,bx
      call word ptr cs:[bx+202h]
      
      ok:
        pop bx
          iret 

;----------sub0======          
    sub0:
     push bx
     push es
     push cx
     
     mov bx,0b800h
     mov es,bx
     mov bx,0
     mov cx,2000
     sub0s:
         mov byte ptr es:[bx],' '
           add bx,2
           loop sub0s
        
     pop cx
     pop es
     pop bx
     ret   ;此子程序也是被调用的，所以同样要返回
  ;-----end
  
  ;-------sub1
  sub1:
      push es
      push bx
      push cx
      
      mov bx,0b800h
      mov es,bx
      mov bx,1
      mov cx,2000
      
      sub1s:
         and byte ptr es:[bx],11111000b
           or es:[bx],al
           add bx,2
           loop sub1s
        pop cx
        pop bx
        pop es
        ret
        
;--------end    ---sub1

 ;----sub2
  sub2:
      push es
      push bx
      push cx
      
      mov cl,4
      shl al,cl
      mov bx,0b800h
      mov es,bx
      mov bx,1
      mov cx,2000
      
      sub2s:
         and byte ptr es:[bx],10001111b
           or es:[bx],al
           add bx,2
           loop sub2s
        pop cx
        pop bx
        pop es
        ret
;0-----end sub2

;00-----sub3
   sub3:
       push es
       push di
       push ds
       push si
       push cx
       
       mov si,0b800h
       mov es,si
       mov ds,si
       mov si,160
       mov di,0
       
       ;mov cx,160*24
       ;cld
       ;rep movsb
       mov cx,24
       sub4:
          push cx
            mov cx,160
            rep movsb
            pop cx
            loop sub4
       
       mov cx,80
       mov si,0
       sub3s:
         mov byte ptr es:[160*24+si],' '
         add si,2
         loop sub3s
     
       pop cx
       pop si
       pop ds
       pop di
       pop es
       ret
       
    ;-=-------end sub3
    int7chend:nop
    
     
    
           
 code ends
 end start