1，可以精简为：
pushf
call dword ptr ds:[0]


2.修改后的程序为

assume cs:code

stack segment
db 128 dup (0)
stack ends

data segment 
dw 0,0
data ends

code segment
start:
mov ax,stack
mov ss,ax
mov sp,128

mov ax,data
mov ds,ax

mov ax,0
mov es,ax


push es:[9*4]
pop ds:[0]
push es:[9*4+2]
pop ds:[2]    ;将原来的int 9中断例程的入口地址保存在ds:[0],dx:[2]单元中

cli
mov word ptr es:[9*4],offset int9
mov es:[9*4+2],cs   ;在中断向量表中设置新的int9中断例程的入口地址
sti

mov ax,0b800h
mov es,ax
mov ah,'a'

s:

mov es:[160*12+40*2],ah
call delay    ;延迟1000000
inc ah      ;下一个字母
cmp ah,'z'  ;看不是不Z
jna s

mov ax,0
mov es,ax
push ds:[0]
pop es:[9*4]
push ds:[2]
pop es:[9*4+2]

mov ax,4c00h
int 21h
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;程序到这里就结束了，下边是上面调用的子程序和更改后的int 9中断
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;这个是延迟的程序
delay:
push ax
push dx
mov dx,1000h
mov ax,0
s1:
sub ax,1
sbb dx,0
cmp ax,0
jne s1
cmp dx,0
jne s1
pop dx
pop ax
ret
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;下边是新的int 9中断例程
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
int9:
push ax
push bx
push es

in al,60h
;pushf
;pushf
;pop bx
;and bh,11111100b
;push bx
;popf
;call dword ptr ds:[0] ;对int指令进行模拟，调用原来的int 9中断

;简化指令为
pushf
call dword ptr ds:[0]

cmp al,1
jne int9ret

mov ax,0b800h
mov es,ax
inc byte ptr es:[160*12+40*2+1] ;将属性值+1，改变颜色

int9ret:
pop es
pop bx
pop ax
iret

code ends
end start