好好欣赏这个程序的逻辑构架，很经典的！！！还有很经典的技巧！
（dh）（dl）=字符串在屏幕上显示的行列位置
assume cs:code
code segment
start: mov dh,12
      mov dl,4
      call getstr
          
      mov ax,4c00h
      int 21h
        
getstr:  push ax

getstrs: mov ah,0    ;用int 16h中断从键盘缓存区取数据
        int 16h          扫描码送入ah,ASCII码送入al
        cmp al,20h   ;ASCII码小于20h，说明不是字符
        jb nochar
        mov ah,0
        call charstack
        jmp getstrs

nochar:  cmp ah,0eh   ;退格键的扫描码
        je backspace
        cmp ah,1ch   ;Enter键的扫描码
        je enter
        jmp getstrs

backspace: mov ah,1
        call charstack
        mov ah,2
        call charstack
        jmp getstrs

enter:  mov al,0
        mov ah,0
        call charstack
        mov ah,2
        call charstack
        pop ax
        ret                
        
;子程序：字符栈的入栈、出栈和显示
;参数说明：（ah）=功能号，0表示入栈，1表示出栈，2表示显示；
;ds:si指向字符栈空间
;对于0号功能：（al）=入栈字符
;对于1号功能：（al）=返回的字符
;对于2号功能：（dh）（dl）=字符串在屏幕上显示的行列位置。
charstack:jmp short charstart
 
table dw charpush,charpop,charshow  ;程序入口的直接定址表
top   dw 0
charstart: push bx
          push dx
          push di
          push es
                  
          cmp ah,2
          ja  sret
          mov bl,ah
          mov bh,0
          add bx,bx
          jmp word ptr table[bx]；与表之间的映射关系
charpush: mov bx,top
         mov [si][bx],al
         inc top 
         jmp sret
                 
charpop : cmp top,0
         je sret
         dec top 
         mov bx,top
         mov al,[si][bx]
         jmp sret

charshow: mov bx,0b800h
         mov es,bx
         mov al,160
         mov ah,0
         mul dh     ;计算行
         mov di,ax
         add dl,dl  ;计算列
         mov dh,0   
         add di,dx  ;得到在屏幕上的位置

         mov bx,0

charshows: cmp bx,top
         jne noempty
         mov byte ptr es:[di],' '
         jmp sret
noempty: mov al,[si][bx]
        mov es:[di],al
        mov byte ptr es:[di+2],' '
        inc bx
        add di,2
        jmp charshows

sret:   pop es
        pop di
        pop dx
        pop bx
        ret                
code ends
end        start