实验 7 寻址方式在结构化数据访问中的应用
本实验的编程代码如下：
方法 1：不使用栈操作
assume cs:code
data segment
db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
db '1993','1994','1995'
; 以上是表示 21 年的 21 个字符串，每个字符串包含 4 个字符，所以共计 84 个字符，占用 84 字节
dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
; 以上是表示 21 年公司总收入的 21 个 dword 型数据，每个数据占用 4 字节，所以共计占用 84 字节
dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
dw 11542,14430,15257,17800
; 以上是表示 21 年公司雇员人数的 21 个 word 型数据，每个数据占用 2 字节，所以共计占用 42 字节
data ends
table segment
db 21 dup ('0000 ',0,0,0,0,' ',0,0,' ',0,0,' ')
table ends
code segment
start: mov ax,data
mov ds,ax
mov di,168 ; DI 寄存器存储着 data 段中 dw 部分数据的偏移地址，168=84+84
mov bx,0
mov ax,table
mov ss,ax
mov bp,0
mov cx,21
; loop u 循环执行 21 次
u: mov si,0
mov dx,cx
mov cx,4
; loop s0 循环执行 4 次，用以复制年份数据和收入数据
s0: mov al,[bx]
mov [bp].[si],al
mov ah,[bx+84]
mov [bp].5[si],ah
inc bx
inc si
loop s0
; 将 data 段“雇员”数据复制到 table 段对应位置
mov ax,[di]
mov [bp].0Ah,ax ; 注意，十六进制数必须在数字前面添加前缀 0
add di,2
mov cx,dx ; 由于计算人均收入需要用到 div 指令，而该指令需要使用 DX 寄存器，所以必须先将 DX 寄存器中存储的 loop u 循环判定值传送回 CX 寄存器
; 计算人均收入，并将计算结果存入 table 段相应位置
mov ax,[bp].5
mov dx,[bp].7
div word ptr [bp].0Ah
mov [bp].0Dh,ax
add bp,10h
loop u
mov ax,4c00h
int 21h
code ends
end start
方法 2：使用栈操作
assume cs:code,es:table,ss:stack
data segment
db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
db '1993','1994','1995'
; 以上是表示 21 年的 21 个字符串，每个字符串包含 4 个字符，所以共计 84 个字符，占用 84 字节
dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
; 以上是表示 21 年公司总收入的 21 个 dword 型数据，每个数据占用 4 字节，所以共计占用 84 字节
dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
dw 11542,14430,15257,17800
; 以上是表示 21 年公司雇员人数的 21 个 word 型数据，每个数据占用 2 字节，所以共计占用 42 字节
data ends
table segment
db 21 dup ('0000 ',0,0,0,0,' ',0,0,' ',0,0,' ')
table ends
stack segment
dw 0,0
stack ends
code segment
start: mov ax,data
mov ds,ax
mov di,168 ; DI 寄存器存储着 data 段中 dw 部分数据的偏移地址，168=84+84
mov bx,0
mov ax,stack
mov ss,ax
mov sp,2
mov ax,table
mov es,ax
mov bp,0
mov cx,21
; loop u 循环执行 21 次
u: mov si,0
mov dx,cx
mov cx,4
; loop s0 循环执行 4 次，用以复制年份数据和收入数据
s0: mov al,[bx]
mov es:[bp].[si],al
mov ah,[bx+84]
mov es:[bp].5[si],ah
inc bx
inc si
loop s0
; 将 data 段“雇员”数据通过栈的 push 和 pop 操作复制到 table 段对应位置
push [di]
pop es:[bp].0Ah
add di,2
mov cx,dx ; 由于计算人均收入需要用到 div 指令，而该指令需要使用 DX 寄存器，所以必须先将 DX 寄存器中存储的 loop u 循环判定值传送回 CX 寄存器
; 计算人均收入，并将计算结果存入 table 段相应位置
mov ax,es:[bp].5
mov dx,es:[bp].7
div word ptr es:[bp].0Ah
mov es:[bp].0Dh,ax
add bp,10h
loop u
mov ax,4c00h
int 21h
code ends
end start
