代码如下：
;Install new int9 interuppt

assume cs:code,ss:stack

stack segment
    db 64 dup (0)
stack ends

code segment
start:
    mov ax,stack
    mov ss,ax
    mov sp,64

    mov ax,0
    mov es,ax
    mov di,204h

    mov ax,cs
    mov ds,ax
    mov si,offset int9

    mov cx,offset int9end - offset int9
    cld
    rep movsb       ;Copy new int9 interrupt program to 0:204h

    push es:[9*4]
    pop es:[200h]
    push es:[9*4+2]
    pop es:[202h]   ;Store old int9 interrupt address at 0:200h

    cli
    mov word ptr es:[9*4],204h
    mov word ptr es:[9*4+2],0   ;Install new int9 interrupte address
    sti

    mov ax,4c00h
    int 21h

int9:
    push ax
    push cx
    push es
    push si

    in al,60h                   ;Read the keyboad input

    pushf
    call dword ptr cs:[200h]    ;Call old int9 interrupt handling

    cmp al,9eh                  ;Compare al with 'A' loose key number '9EH'
    jne int9ret                 ;If not,just simply return

    mov cx,0b800h
    mov es,cx
    mov cx,2000                 ;Otherwise display 'A' all monitor
    mov ah,'A'
    mov si,0
s:
    mov es:[si],ah
    add si,2
    loop s

int9ret:
    pop si
    pop es
    pop cx
    pop ax
    iret

int9end:
    nop

code ends
end start